Stylesheet documentation for: paragraphs.xsl

Description

TEI stylesheet for converting Word docx files to TEI

This software is dual-licensed: 1. Distributed under a Creative Commons Attribution-ShareAlike 3.0 Unported License http://creativecommons.org/licenses/by-sa/3.0/ 2. http://www.opensource.org/licenses/BSD-2-Clause All rights reserved. Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met: * Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer. * Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution. This software is provided by the copyright holders and contributors "as is" and any express or implied warranties, including, but not limited to, the implied warranties of merchantability and fitness for a particular purpose are disclaimed. In no event shall the copyright holder or contributors be liable for any direct, indirect, incidental, special, exemplary, or consequential damages (including, but not limited to, procurement of substitute goods or services; loss of use, data, or profits; or business interruption) however caused and on any theory of liability, whether in contract, strict liability, or tort (including negligence or otherwise) arising in any way out of the use of this software, even if advised of the possibility of such damage.

Author: See AUTHORS

Id: $Id: paragraphs.xsl 12181 2013-05-31 16:59:49Z rahtz $

Description

Calls the named template paragraph-wp that can be overriden.

See comment at begin of document to understand why this template is calling a named template. This stylesheet is handling simple paragraphs that we know nothing else about.

Template

paragraph-wp

<xsl:template match="w:p" mode="paragraph">
  <xsl:variable name="style" select="w:pPr/w:pStyle/@w:val"/>
  <xsl:choose>
    <xsl:when test="$style='tei_lg'"/>
    <xsl:when test="$style='GeneratedTitle'"/>
    <xsl:when test="$style='GeneratedSubTitle'"/>
    <xsl:when test="$style='tei_l'">
      <l>
        <xsl:apply-templates/>
      </l>
    </xsl:when>
    <xsl:when test="$style='Tabletitle'">
      <head>
        <xsl:apply-templates/>
      </head>
    </xsl:when>
    <xsl:when test="$style='dl'">
      <GLOSSITEM>
        <xsl:apply-templates/>
      </GLOSSITEM>
    </xsl:when>
    <xsl:when test="$style='tei_signed'">
      <signed>
        <xsl:apply-templates/>
      </signed>
    </xsl:when>
    <xsl:when test="$style='tei_speaker'">
      <speaker>
        <xsl:apply-templates/>
      </speaker>
    </xsl:when>
    <xsl:when test="$style='tei_speech'">
      <speech>
        <xsl:apply-templates/>
      </speech>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="paragraph-wp">
        <xsl:with-param name="style" select="$style"/>
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Description

Named template for handling w:p; we use the Word style (if provided) to make a TEI rend attribute, and check for change records.

Template

w:pparagraph

QName	Namespace
style	No namespace

<xsl:template name="paragraph-wp">
  <xsl:param name="style"/>
  <xsl:element name="p">
    <xsl:if test="$style and not($style='Default')">
      <xsl:attribute name="rend">
        <xsl:value-of select="$style"/>
      </xsl:attribute>
    </xsl:if>
    <xsl:if test="w:pPr/w:pStyle/w:rPr/w:rtl">
      <xsl:attribute name="dir" xmlns="http://www.w3.org/2005/11/its">
        <xsl:text>rtl</xsl:text>
      </xsl:attribute>
    </xsl:if>
    <xsl:choose>
      <xsl:when test="w:pPr/w:rPr/w:ins and $processChangeInformation='true'">
        <add when="{w:pPr/w:rPr/w:ins/@w:date}" type="para">
          <xsl:call-template name="identifyChange">
            <xsl:with-param name="who" select="w:pPr/w:rPr/w:ins/@w:author"/>
          </xsl:call-template>
          <xsl:call-template name="process-checking-for-crossrefs"/>
        </add>
      </xsl:when>
      <xsl:otherwise>
        <xsl:call-template name="process-checking-for-crossrefs"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:element>
</xsl:template>

Description

Named template for processing of any cross-references found.

Template

paragraph-wp

<xsl:template name="process-checking-for-crossrefs">
  <xsl:choose>
    <xsl:when test="w:r/w:fldChar[@w:fldCharType='begin']">
      <xsl:for-each-group select="w:*|m:*" group-starting-with="w:r[w:fldChar/@w:fldCharType[matches(.,'begin|end')]]">
        <xsl:choose>
          <xsl:when test="self::w:r/w:fldChar[@w:fldCharType='begin']">
            <xsl:variable name="rends">
              <!-- collect all the rends for concatenation later
		  -->
              <xsl:variable name="instruction" select="following-sibling::w:r[w:instrText[not(normalize-space(.)='')]][1]"/>
              <xsl:choose>
                <xsl:when test="contains($instruction,'NOTEREF')">
                  <r>noteref</r>
                </xsl:when>
                <xsl:when test="contains($instruction,'SEQ')">
                  <r>SEQ</r>
                </xsl:when>
                <xsl:when test="contains($instruction,'XE')">
                  <r>index</r>
                </xsl:when>
                <xsl:when test="contains($instruction,'REF')">
                  <r>ref</r>
                </xsl:when>
              </xsl:choose>
              <xsl:if test="contains($instruction,'\r')">
                <r>instr_r</r>
              </xsl:if>
              <xsl:if test="contains($instruction,'\f')">
                <r>instr_f</r>
              </xsl:if>
              <xsl:if test="contains($instruction,'\n')">
                <r>instr_n</r>
              </xsl:if>
              <xsl:if test="contains($instruction,'MERGEFORMAT')">
                <r>mergeformat</r>
              </xsl:if>
            </xsl:variable>
            <xsl:choose>
              <xsl:when test="$rends/tei:r='index'">
                <xsl:call-template name="process-index-term">
                  <xsl:with-param name="term">
                    <xsl:for-each select="current-group()//w:instrText">
                      <xsl:apply-templates/>
                    </xsl:for-each>
                  </xsl:with-param>
                </xsl:call-template>
              </xsl:when>
              <!--
		  <xsl:when test="$rends/tei:r='SEQ'">
		    <xsl:variable name="What"
		       select="following-sibling::w:r/w:instrText[1]"/>
		       <xsl:number level="any" count="w:r[w:fldChar/@w:fldCharType='begin'][following-sibling::w:r/w:instrText=$What]"/>
		  </xsl:when>
		  -->
              <xsl:otherwise>
                <ref>
                  <xsl:if test="$rends/tei:r">
                    <xsl:attribute name="rend">
                      <xsl:value-of select="string-join(($rends/tei:r),' ')"/>
                    </xsl:attribute>
                  </xsl:if>
                  <xsl:if test="following-sibling::w:r[w:rPr][1]/w:rStyle">
                    <xsl:attribute name="iso:class">
                      <xsl:value-of select="following-sibling::w:r[w:rPr][1]/w:rStyle/w:rPr/w:rStyle/@w:val"/>
                    </xsl:attribute>
                  </xsl:if>
                  <xsl:for-each select="current-group()">
                    <xsl:if test="self::w:r[w:instrText]">
                      <xsl:variable name="ref">
                        <xsl:choose>
                          <xsl:when test="contains(w:instrText,'REF _')">
                            <!-- this will also catch NOTEREF _ -->
                            <xsl:text>#</xsl:text>
                            <xsl:value-of select="substring-before(substring-after(w:instrText,'_'),' ')"/>
                          </xsl:when>
                          <xsl:when test="contains(w:instrText,'HYPERLINK')">
                            <xsl:value-of select="substring-before(substring-after(w:instrText,'"'),'"')"/>
                          </xsl:when>
                        </xsl:choose>
                      </xsl:variable>
                      <xsl:if test="not($ref='')">
                        <xsl:attribute name="target" select="$ref"/>
                      </xsl:if>
                    </xsl:if>
                  </xsl:for-each>
                  <xsl:for-each select="current-group()">
                    <xsl:choose>
                      <xsl:when test="self::w:bookmarkStart">
                        <xsl:apply-templates select="."/>
                      </xsl:when>
                      <xsl:otherwise>
                        <xsl:apply-templates select="."/>
                      </xsl:otherwise>
                    </xsl:choose>
                  </xsl:for-each>
                </ref>
              </xsl:otherwise>
            </xsl:choose>
          </xsl:when>
          <xsl:when test="self::w:r[w:fldChar/@w:fldCharType[matches(.,'end')]]">
            <xsl:for-each select="current-group()">
              <xsl:choose>
                <xsl:when test="self::w:r[w:fldChar/@w:fldCharType[matches(.,'end')]]">
                </xsl:when>
                <xsl:otherwise>
                  <xsl:apply-templates select="."/>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:for-each>
          </xsl:when>
          <xsl:otherwise>
            <xsl:apply-templates select="current-group()"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each-group>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Description

Named template for handling processing of index terms. First insert main index enty, then recurse by index level

Variables	dblq; usr; ust
Template	process-index-term

QName	Namespace
term	No namespace
xr	No namespace

<xsl:template name="process-index-term">
  <xsl:param name="term"/>
  <xsl:param name="xr"/>
  <!--xsl:message>[<xsl:value-of select="$term"/>]</xsl:message-->
  <xsl:choose>
    <xsl:when test="starts-with($term,'XE') or starts-with($term,' XE')">
      <xsl:variable name="quoted-text" select="concat('[^',$dblq,']+',$dblq,'([^',$dblq,']+)',$dblq,'.*')"/>
      <xsl:variable name="clean-term" select="fn:replace($term,$quoted-text,'$1')"/>
      <xsl:variable name="span" select="fn:replace(substring-after($term,$usr),$quoted-text,'$1')"/>
      <xsl:variable name="see">
        <xsl:value-of select="fn:replace(substring-after($term,$ust),$quoted-text,'$1')"/>
      </xsl:variable>
      <index indexName="XE">
        <xsl:if test="normalize-space($span)">
          <xsl:attribute name="spanTo">
            <xsl:text>#</xsl:text>
            <xsl:value-of select="normalize-space($span)"/>
          </xsl:attribute>
        </xsl:if>
        <xsl:call-template name="process-index-term">
          <xsl:with-param name="term" select="normalize-space($clean-term)"/>
          <xsl:with-param name="xr" select="normalize-space($see)"/>
        </xsl:call-template>
      </index>
    </xsl:when>
    <xsl:when test="contains($term,':')">
      <xsl:call-template name="process-index-term">
        <xsl:with-param name="term" select="substring-before($term,':')"/>
      </xsl:call-template>
      <index>
        <xsl:call-template name="process-index-term">
          <xsl:with-param name="term" select="substring-after($term,':')"/>
          <xsl:with-param name="xr" select="normalize-space($xr)"/>
        </xsl:call-template>
      </index>
    </xsl:when>
    <xsl:when test="normalize-space($term)">
      <term>
        <xsl:value-of select="normalize-space($term)"/>
        <xsl:if test="normalize-space($xr)">
          <ref>
            <xsl:value-of select="normalize-space($xr)"/>
          </ref>
        </xsl:if>
      </term>
    </xsl:when>
  </xsl:choose>
</xsl:template>

<xsl:variable name="dblq">"</xsl:variable>

<xsl:variable name="usr">\r</xsl:variable>

<xsl:variable name="ust">\t</xsl:variable>

Stylesheet documentation generated by <oXygen/>^® XML Editor.

Mode:

Showing:

Description

Description

Description

Description

Description